SNES master cycle viewer

Assembler

Note

It is a simple assembler and does not have advanced functions.

Since strict addressing optimization is not performed, please add a length specification as necessary.

Instruction syntax

Addressing	Syntax	Example
Implied	(none)	NOP
Accumulator	(none) A	ASL ASL A
Stack	(none)	RTS
Immediate	#imm .b #imm .w #imm	LDA #$00 LDA.b #$01 LDA.w #$01
Direct page	dp .b dp	LDA $00 LDA.b $00
Direct page Indexed, X	dp, X .b dp, X	LDA $00, X LDA.b $00, X
Direct page Indexed, Y	dp, Y .b dp, Y	LDA $00, Y LDA.b $00, Y
Direct page Indirect	(dp)	LDA ($00)
Direct page Indexed Indirect, X	(dp, X)	LDA ($00, X)
Direct page Indirect Indexed, Y	(dp), Y	LDA ($00), Y
Direct page Indirect Long	[dp]	LDA [$00]
Direct page Indirect Long Indexed, Y	[dp], Y	LDA [$00], Y
Absolute	abs .w abs	LDA $0000 LDA.w $0000
Absolute Indexed, X	abs, X .w abs, X	LDA $0000, X LDA.w $0000, X
Absolute Indexed, Y	abs, Y .w abs, Y	LDA $0000, Y LDA.w $0000, Y
Absolute Indirect	(abs)	JMP ($0123)
Absolute Indexed Indirect	(abs, X)	JMP ($0123, X)
Absolute Indirect Long	[abs]	JMP [$0123]
Absolute Long	long .l long	LDA $000000 LDA.l $000000
Absolute Long Indexed, X	long, X .l long	LDA $000000, X LDA.l $000000, X
Relative	rel	BEQ Label
Relative Long	rlong	BRL Label
Stack Relative	sr, S	LDA $00, S
Stack Relative Indirect Indexed, Y	(sr, S), Y	LDA ($00, S), Y
Block Move	src, dst	MVP $00, $01

Directive

Name	Syntax	Example
Origin	.org address	.org $008000
Byte array	.db value, value, value, ...	.db $00, 1, "ABC", Label
Word array	.dw value, value, value, ...	.dw $00, 1, "ABC", Label
Long array	.dl value, value, value, ...	.dl $00, 1, "ABC", Label
Dword array	.dd value, value, value, ...	.dd $00, 1, "ABC", Label
Memory short	.m8	.m8 LDA #0 ; A9 00
Memory long	.m16	.m16 LDA #0 ; A9 00 00
Index short	.i8	.i8 LDX #0 ; A2 00
Index long	.i16	.i16 LDX #0 ; A2 00 00
Direct pointer value	.dp value	.org $008000 .dp $0123 LDA $0124 ; A5 01

Label

Name	Syntax	Example
Global label	Label:	Label:
Local label	.Label	Label: .Local
Unnamed label (Forward)	+	BRA + + NOP
Unnamed label (Backward)	-	- NOP BRA -

Define

Name	Syntax	Example
Define	Name = Value	Counter = $13 INC Counter ; E6 13
Local define	.Name = Value	Label: .Temporary = $0A STA .Temporary ; 85 0A

Comment

Name	Syntax	Example
Single line	; ... // ...	; comment // comment

Expression

Operators are evaluated left to right with no associative order.

Name	Syntax	Example
Addition	+	LDA.b #$12+3 ; A9 15
Subtraction	-	LDA.b #$12-3 ; A9 0F
Multiplication	*	LDA.b #$12*3 ; A9 36
Division	/	LDA.b #$12/3 ; A9 06
Modulo	%	LDA.b #$12%3 ; A9 00
Logical shift left	<<	LDA.b #$12<<3 ; A9 90
Logical shift right	>>	LDA.b #$12>>3 ; A9 02
Bitwise AND	&	LDA.b #$12&3 ; A9 02
Bitwise OR	\|	LDA.b #$12\|3 ; A9 13
Bitwise XOR	^	LDA.b #$12^3 ; A9 11
Negative	-	LDA.b #-$12 ; A9 EE

Emulation

I/O Registers

Register	Address	Access	Note
M7A	$211B	Write	for PPU multiplication
M7B	$211C	Write	for PPU multiplication
MPYL	$2134	Read
MPYM	$2135	Read
MPYB	$2136	Read
WRMPYA	$4202	Write
WRMPYB	$4203	Write
WRDIVL	$4204	Write
WRDIVH	$4205	Write
WRDIVB	$4206	Write
MEMSEL	$420D	Write
RDMPYL	$4216	Read
RDMPYH	$4217	Read
DMA parameters	$43nX	Read/Write	for fast RAM

Note

Does not emulate DRAM refresh to account for worst case cycle calculations.

Sample

Initialized memory

Set the address of the RAM with the .org directive to give an initial value.

		.m8 .i8
Start:		LDY	#$00

		LDA	Target1		; A = $AA
		LDA	(Target2), Y	; A = $BB
		STP

		.org	$0111
Target1:	.db	$AA

		.org	$0022
Target2:	.dw	.Pointer

		.org	$0333
.Pointer	.db	$BB

Block move

Start:		REP	#$30
		.m16 .i16

		; Copy $008000 to $000000, $123 bytes
		LDA	#$123
		LDX	#$8000
		LDY	#$0000
                MVN	Start>>16, $00	; src, dst

		LDA	$0123		; A = $BBAA
		STP

		.org	$008123
		.db	$AA, $EE

		.org	$0123
		.db	$FF, $BB

Manual FastROM change

Either change the start address or jump to the FastROM area.

MEMSEL	= $420D

		;.org $808000
		.m8 .i8
Start:		LDA.b	$00	; Slow,Slow,Slow

		LDA	#$01
		STA.w	MEMSEL	; enable FastROM

		LDA.b	$00	; Fast,Fast,Slow

		STP

DMA registers as fast RAM

DMAP0		= $4300
DMAUNKNOWN7B	= $437B
DMAUNKNOWN7F	= $437F

Start:		REP	#$10
		.m8 .i16

		LDX	#DMAUNKNOWN7B
		TXS		; S = $437B

		JSR	Sub
		STP

Sub:
		; Mirrored fast RAM
		LDA	DMAUNKNOWN7F
		STA	DMAUNKNOWN7B
		RTS

5A22 MPY, DIV and PPU MPY

M7A     = $211B
M7B     = $211C
MPYL    = $2134
MPYM    = $2135
MPYH    = $2136
WRMPYA	= $4202
WRMPYB	= $4203
WRDIVL	= $4204
WRDIVH	= $4205
WRDIVB	= $4206
RDDIVL	= $4214
RDDIVH	= $4215
RDMPYL	= $4216
RDMPYH	= $4217

Start:
.Result5A22MPY	= $00
.Result5A22DIV	= $04
.ResultPPUMPY	= $08

		REP	#$10
		.m8 .i16

		; 5A22 MPY: $AA * $BB = $7C2E
		LDA	#$AA
		STA	WRMPYA
		LDA	#$BB
		STA	WRMPYB
		LDA	RDMPYL	;  4 (dummy)
		LDX	RDMPYL	;  8
		STX	.Result5A22MPY

		; 5A22 DIV: $AABB / 100 = $01B5 mod $0007
		LDX	#$AABB
		STX	WRDIVL
		LDA	#100
		STA	WRDIVB
		LDA	RDDIVL	;  4 (dummy)
		LDA	RDDIVL	;  8 (dummy)
		LDA	RDDIVL	; 12 (dummy)
		LDX	RDDIVL	; 16
		LDY	RDMPYL	; 21
		STX	.Result5A22DIV + 0
		STY	.Result5A22DIV + 2

                ; PPU MPY: $0123 * $AB = $FF9F61
		LDA	#$01
		STA	M7A
		LDA	#$23
		STA	M7A     ; M7A = $AABB
		LDA	#$55
		STA	M7B
		LDA	#$AB
		STA	M7B	; M7B = $55AB ($AB)
		LDA	MPYL
		LDX	MPYM
		LDY	MPYH
		STA	.ResultPPUMPY + 0
		STX	.ResultPPUMPY + 1

		STP

Definition using local labels

Local labels and local definitions within definitions are referenced from the defined scope.

		;.org $008000
		.m8 .i8
L1:
.T	= $01
-		LDA	Target1		; $008000: AD 08 80	; L2 minus
		LDA	#Target2	; $008003: A9 01
		LDA	#Target3	; $008005: A9 02	; L2 .T
L2:
.T	= $02
		NOP			; $008007: EA
-		NOP			; $008008: EA
.a		NOP			; $008009: EA
		BEQ	-		; $00800A: F0 FC
		STP			; $00800C: DB

; Definition using L2 scope local label
Target1	= -		; $008008
Target2	= .a - -	; $008009 - $008008 = $01
Target3	= .T		; $02

Heatmap not mapped to source code

The heatmap does not show line numbers for dynamic code in RAM.

		.m8 .i8
Start:
		; Copy to RAM
		LDX	#RamCodeLength - 1
-		LDA	RamCode, X
		STA	RamCodeAddress, X
		DEX
		BPL	-

		; Change RAM code operand
		LDA	#$AA
		STA	RamCodeAddress + 1
		LDA	#$BB
		STA	RamCodeAddress + 4
		LDA	#$CC
		STA	RamCodeAddress + 3

		; Call RAM code
		JSR	RamCodeAddress

		STP		; loooooooooooooooooooooooooooooong comment

RamCode:	LDA	#$00
		STA.w	$0000
		RTS
.End
RamCodeAddress	= $1000
RamCodeLength	= .End - RamCode

Execute openbus

$00-3F,80-BF:2000-5FFF with no I/O registers, LoROM maps $00-3F,80-BF:6000-7FFF and HiROM maps $00-0F,80-8F:6000-7FFF as open buses.

		.m8 .i8
Start:		LDX	#$AA
		JML	$015000	; jump to openbus

		.org	$01BBBB
Return:		STP		; return address from openbus

		.org	$AB	; $01 + $AA
		.dw	$2525	; AND dp

		.org	$25
		.dw	$FC	; JSR (abx, X)

		.org	$07A6	; $06FC + $AA
		.dw	Return